48 lines
1.0 KiB
Bash
48 lines
1.0 KiB
Bash
# Maintainer: Luke T. Shumaker <lukeshu@umorpha.io>
|
|
|
|
pkgbase=umorpha-eclipse
|
|
pkgname=(umorpha-eclipse-leader umorpha-eclipse-follower umorpha-eclipse-admin)
|
|
pkgver=0.1
|
|
pkgrel=1
|
|
arch=('x86_64')
|
|
pkgdesc='Umorpha Eclipse CI job manager'
|
|
url="https://git.mothstuff.lol/lukeshu/eclipse"
|
|
license=('AGPL')
|
|
depends=(git sqlite)
|
|
makedepends=(git go)
|
|
source=("git+https://git.mothstuff.lol/lukeshu/eclipse.git#commit=a4540f9a56f2c9929d30405b6be8abbf51aa1d6b")
|
|
sha256sums=('SKIP')
|
|
|
|
_config=(
|
|
prefix=/usr
|
|
sysconfdir=/etc
|
|
localstatedir=/var
|
|
runstatedir=/run
|
|
)
|
|
|
|
build() {
|
|
cd eclipse
|
|
make "${_config[@]}"
|
|
}
|
|
|
|
package_umorpha-eclipse-leader() {
|
|
pkgdesc+=' - central leader programs'
|
|
|
|
cd eclipse
|
|
make "${_config[@]}" DESTDIR="$pkgdir" install-leader
|
|
}
|
|
|
|
package_umorpha-eclipse-follower() {
|
|
pkgdesc+=' - follower programs'
|
|
|
|
cd eclipse
|
|
make "${_config[@]}" DESTDIR="$pkgdir" install-follower
|
|
}
|
|
|
|
package_umorpha-eclipse-admin() {
|
|
pkgdesc+=' - administration tools'
|
|
|
|
cd eclipse
|
|
make "${_config[@]}" DESTDIR="$pkgdir" install-admin
|
|
}
|