# Maintainer: Luke T. Shumaker <lukeshu@umorpha.io>

pkgbase=umorpha-eclipse
pkgname=(umorpha-eclipse-leader umorpha-eclipse-follower umorpha-eclipse-admin)
pkgver=0.5
pkgrel=1
arch=('x86_64')
pkgdesc='Umorpha Eclipse CI job manager'
url="https://git.mothstuff.lol/lukeshu/eclipse"
license=('AGPL')
depends=(git sqlite)
makedepends=(git go)
source=("git+https://git.mothstuff.lol/lukeshu/eclipse.git#commit=0d0d626099a78c6532bd94af3a69863c34296eee")
sha256sums=('SKIP')

_config=(
	prefix=/usr
	sysconfdir=/etc
	localstatedir=/var
	runstatedir=/run
)

build() {
	cd eclipse
	make "${_config[@]}"
}

package_umorpha-eclipse-leader() {
	pkgdesc+=' - central leader programs'

	cd eclipse
	make "${_config[@]}" DESTDIR="$pkgdir" install-leader
}

package_umorpha-eclipse-follower() {
	pkgdesc+=' - follower programs'

	cd eclipse
	make "${_config[@]}" DESTDIR="$pkgdir" install-follower
}

package_umorpha-eclipse-admin() {
	pkgdesc+=' - administration tools'

	cd eclipse
	make "${_config[@]}" DESTDIR="$pkgdir" install-admin
}